home *** CD-ROM | disk | FTP | other *** search
/ EnigmA Amiga Run 1995 November / EnigmA AMIGA RUN 02 (1995)(G.R. Edizioni)(IT)[!][issue 1995-11][Skylink CD].iso / earcd / giochi / aboulder.lha / ABoulderDash1.0 / start.s < prev    next >
Text File  |  1995-08-27  |  13KB  |  692 lines
  1.     opt    L+
  2.     opt    O2+
  3.     opt    OW-
  4.  
  5. *==========================================
  6. *
  7. * File:        start.s
  8. * Version:     1
  9. * Revision:    0
  10. * Created:     3-VII-1993
  11. * By:          FNC Slothouber
  12. * Last Update: 25-Aug-1995
  13. * By:          FNC Slothouber
  14. *
  15. *==========================================
  16.  
  17.     incdir    "include:"
  18.  
  19.     include graphics/graphics_lib.i
  20.     include graphics/gfxbase.i
  21.     include    graphics/view.i
  22.     include hardware/custom.i
  23.     include hardware/intbits.i
  24.     include    exec/exec_lib.i
  25.     include exec/memory.i
  26.     include exec/nodes.i
  27.     include exec/interrupts.i
  28.     include    workbench/startup.i
  29.  
  30.     include    libraries/dos_lib.i
  31.     include    libraries/dos.i
  32.  
  33.     include    ExtGfx.i
  34.  
  35.     include    reqtools/reqtools.i
  36.  
  37.     include execmacros.i
  38.     include    boulderdash.i
  39.  
  40.     XDEF    grid_field
  41.     XDEF    _ExtGfxBase
  42.     XDEF    _IntuitionBase
  43.     XDEF    _GfxBase
  44.     XDEF    _ReqToolsBase
  45.     XDEF    _DOSBase
  46.     XDEF    bitmap1
  47.     XDEF    bitmap2
  48.     XDEF    st_bitmap1
  49.     XDEF    st_bitmap2
  50.     XDEF    bitmapg
  51.     XDEF    display
  52.  
  53.     XDEF    list1
  54.     XDEF    list2
  55.     XDEF    list2_right4
  56.     XDEF    list2_right12
  57.     XDEF    list1_right8
  58.     XDEF    list2_left4
  59.     XDEF    list2_left12
  60.     XDEF    list1_left8
  61.  
  62.     XDEF    list2_up4
  63.     XDEF    list2_up12
  64.     XDEF    list1_up8
  65.     XDEF    list2_down4
  66.     XDEF    list2_down12
  67.     XDEF    list1_down8
  68.  
  69.     XDEF    colors
  70.  
  71.     XREF    Start_Editor
  72.     XREF    Stop_Editor
  73.     XREF    Field_Editor
  74.  
  75.     XREF    AllocRasters
  76.     XREF    FreeRasters
  77.     XREF    EG_AllocBitMap
  78.     XREF    EG_FreeBitMap
  79.     XREF    GetPicture
  80.     XREF    ClearBitMap
  81.     XREF    GetDisplay
  82.     XREF    FreeDisplay
  83.     XREF    CreatePort
  84.     XREF    DeletePort
  85.     XREF    CreateStdIO
  86.     XREF    CreateExtIO
  87.     XREF    DeleteStdIO
  88.     XREF    DeleteExtIO
  89.  
  90.  
  91. CALLEXT        macro
  92.         jsr    \1
  93.         endm
  94.  
  95.     IFND    EXEC_EXEC_I
  96.     include    "exec/exec.i"
  97.     ENDC
  98.     IFND    LIBRARIES_DOSEXTENS_I
  99.     include    "libraries/dosextens.i
  100.     ENDC
  101.  
  102.  
  103.     movem.l    d0/a0,-(sp)        save initial values
  104.     clr.l    returnMsg
  105.  
  106.     sub.l    a1,a1
  107.     EXECCALL FindTask        find us
  108.     move.l    d0,a4
  109.  
  110.     tst.l    pr_CLI(a4)
  111.     beq.s    fromWorkbench
  112.  
  113. * we were called from the CLI
  114.     movem.l    (sp)+,d0/a0        restore regs
  115.     bra    end_startup        and run the user prog
  116.  
  117. * we were called from the Workbench
  118. fromWorkbench
  119.     lea    pr_MsgPort(a4),a0
  120.     EXECCALL WaitPort        wait for a message
  121.     lea    pr_MsgPort(a4),a0
  122.     EXECCALL GetMsg            then get it
  123.     move.l    d0,returnMsg        save it for later reply
  124.  
  125. * do some other stuff here RSN like the command line etc
  126.     nop
  127.  
  128.     movem.l    (sp)+,d0/a0        restore
  129. end_startup
  130.     bsr.s    _main            call our program
  131.  
  132. * returns to here with exit code in d0
  133.     move.l    d0,-(sp)        save it
  134.  
  135.     tst.l    returnMsg
  136.     beq.s    exitToDOS        if I was a CLI
  137.  
  138.     EXECCALL Forbid
  139.     move.l    returnMsg(pc),a1
  140.     EXECCALL ReplyMsg
  141.  
  142. exitToDOS
  143.     move.l    (sp)+,d0        exit code
  144.     rts
  145.  
  146. * startup code variable
  147. returnMsg    dc.l    0
  148.  
  149. * the program starts here
  150.     even
  151.  
  152. _main    move.l    sp,old_stack
  153.  
  154. * Try to open Intuition library
  155.  
  156.     OPENLIB IntName
  157.     move.l  d0,_IntuitionBase
  158.     beq    CleanUp            Intuition library did not open
  159.  
  160. * Try to open Graphics library
  161.  
  162.     OPENLIB GFXName
  163.     move.l  d0,_GfxBase
  164.     beq    CleanUp            GFX library did not open
  165.  
  166. * Try to open Dos library
  167.  
  168.     OPENLIB DosName
  169.     move.l  d0,_DOSBase
  170.     beq    CleanUp            DOS library did not open
  171.  
  172. * Try to open ReqTools library
  173.  
  174.     OPENLIB ReqToolsName
  175.     move.l  d0,_ReqToolsBase
  176.     beq    CleanUp            REQTOOLS library did not open
  177.  
  178.  
  179. * 
  180.  
  181.     move.l    returnMsg,d0
  182.     beq    .clistart
  183.  
  184.     move.l    d0,a0
  185.     move.l    sm_NumArgs(a0),d0
  186.     beq    .clistart
  187.  
  188.     move.l    sm_ArgList(a0),a0
  189.     move.l    (a0),d1
  190.     DOSCALL CurrentDir
  191.  
  192. .clistart
  193.  
  194. * Alloc Memory for Grid Field
  195.  
  196.     move.l    #GRIDF_SIZE,d0
  197.     move.l    #MEMF_PUBLIC|MEMF_CLEAR,d1
  198.     EXECCALL AllocMem
  199.     move.l    d0,grid_field
  200.     beq    CleanUp
  201.  
  202. * Allocate BitMap 1
  203.     move.l    #BM_d,d0        ; Allocate a bitmap
  204.     move.l    #BM_x,d1
  205.     move.l    #BM_y,d2
  206.     CALLEXT EG_AllocBitMap
  207.     move.l    d0,bitmap1
  208.     beq    CleanUp
  209.  
  210. * Allocate BitMap 2
  211.     move.l    #BM_d,d0        ; Allocate a bitmap
  212.     move.l    #BM_x,d1
  213.     move.l    #BM_y,d2
  214.     CALLEXT EG_AllocBitMap
  215.     move.l    d0,bitmap2
  216.     beq    CleanUp
  217.  
  218. * Allocate Bitmap for graphics images
  219.     move.l    #GRAPHICS_d,d0        ; Allocate a bitmap
  220.     move.l    #GRAPHICS_x,d1
  221.     move.l    #GRAPHICS_y,d2
  222.     CALLEXT EG_AllocBitMap
  223.     move.l    d0,bitmapg
  224.     beq    CleanUp
  225.  
  226. * Allocate BitMap 1 For status display
  227.     move.l    #ST_BM_d,d0
  228.     move.l    #ST_BM_x,d1
  229.     move.l    #ST_BM_y,d2
  230.     CALLEXT EG_AllocBitMap
  231.     move.l    d0,st_bitmap1
  232.     beq    CleanUp
  233.  
  234. * Allocate BitMap 2 status display
  235.     move.l    #ST_BM_d,d0
  236.     move.l    #ST_BM_x,d1
  237.     move.l    #ST_BM_y,d2
  238.     CALLEXT EG_AllocBitMap
  239.     move.l    d0,st_bitmap2
  240.     beq    CleanUp
  241.  
  242. * Load Images
  243.  
  244.     lea    graphics_file_name,a0
  245.     move.l    bitmapg,a1
  246.     lea    colors,a2
  247.     CALLEXT GetPicture
  248.  
  249. * Get a display
  250.     move.l    bitmap1,a0    ; allocate a display structure.
  251.     suba.l    a1,a1
  252.     lea    new_disp,a2    ; Display Definition
  253.     CALLEXT    GetDisplay
  254.     move.l    d0,display
  255.     beq    CleanUp
  256.  
  257. * Create additional Viewport for status display
  258.     moveq.l    #32,d0
  259.     GRAFCALL GetColorMap
  260.     move.l    d0,status_color_map
  261.     beq    CleanUp
  262.  
  263.     lea    status_view_port,a0
  264.     GRAFCALL InitVPort
  265.     lea    status_view_port,a0
  266.     lea    status_rastinfo,a1
  267.     move.l    st_bitmap1,ri_BitMap(a1)
  268.     move.l    a1,vp_RasInfo(a0)
  269.     move.w    #ST_BM_x,vp_DWidth(a0)
  270.     move.w    #ST_BM_y,vp_DHeight(a0)
  271.     move.w    #V_SPRITES,vp_Modes(a0)
  272.     move.l    status_color_map,vp_ColorMap(a0)
  273.  
  274.     move.l    display,a2
  275.     move.l    dsp_ViewPort(a2),a1    link old Viewport to niew Viewport
  276.     move.l    a1,vp_Next(a0)
  277.     move.l    dsp_View(a2),a1        link new viewport to view
  278.     move.l    a0,v_ViewPort(a1)
  279.  
  280. * Remember the old view
  281.     move.l    _GfxBase,a0
  282.     move.l    $22(a0),oldview
  283.  
  284. * Define Colors
  285.  
  286.     move.l    display,a2        ; Load the colors
  287.     move.l    dsp_ViewPort(a2),a0
  288.     lea    colors,a1
  289.     move.l    #32,d0
  290.     GRAFCALL LoadRGB4
  291.  
  292.     lea    status_view_port,a0
  293.     lea    colors,a1
  294.     move.l    #32,d0
  295.     GRAFCALL LoadRGB4
  296.  
  297. * Do the graphics stuff
  298.     move.l    display,a2        ; Make a copperlist to display view
  299.  
  300. * scroll zero bitmap 1
  301.     lea    status_view_port,a0
  302.     move.w    #0,vp_DyOffset(a0)
  303.     move.w    #16,vp_DxOffset(a0)
  304.  
  305.     move.l    dsp_ViewPort(a2),a0    ; make room for status display
  306.     move.w    #25,vp_DyOffset(a0)
  307.     move.w    #16,vp_DxOffset(a0)
  308.  
  309.     move.l    dsp_RasInfo(a2),a0
  310.     move.w    #32+16,ri_RxOffset(a0)    ; offset into bitmap
  311.     move.w    #32+16,ri_RyOffset(a0)
  312.  
  313.     bsr    Make_Copper_List
  314.  
  315.     move.l    dsp_View(a2),a0
  316.     move.l    v_LOFCprList(a0),list1
  317.     move.l    #0,v_LOFCprList(a0)
  318.  
  319. * scroll right 8 bitmap 1
  320.  
  321.     move.l    dsp_RasInfo(a2),a0
  322.     move.w    #32+16-8,ri_RxOffset(a0)    ; offset into bitmap
  323.     move.w    #32+16,ri_RyOffset(a0)
  324.  
  325.     bsr    Make_Copper_List
  326.  
  327.     move.l    dsp_View(a2),a0
  328.     move.l    v_LOFCprList(a0),list1_right8
  329.     move.l    #0,v_LOFCprList(a0)
  330.  
  331. * scroll left 8 bitmap 1
  332.  
  333.     move.l    dsp_RasInfo(a2),a0
  334.     move.w    #32+16+8,ri_RxOffset(a0)    ; offset into bitmap
  335.     move.w    #32+16,ri_RyOffset(a0)
  336.  
  337.     bsr    Make_Copper_List
  338.  
  339.     move.l    dsp_View(a2),a0
  340.     move.l    v_LOFCprList(a0),list1_left8
  341.     move.l    #0,v_LOFCprList(a0)
  342.  
  343. * scroll up 8 bitmap 1
  344.  
  345.     move.l    dsp_RasInfo(a2),a0
  346.     move.w    #32+16,ri_RxOffset(a0)    ; offset into bitmap
  347.     move.w    #32+16+8,ri_RyOffset(a0)
  348.  
  349.     bsr    Make_Copper_List
  350.  
  351.     move.l    dsp_View(a2),a0
  352.     move.l    v_LOFCprList(a0),list1_up8
  353.     move.l    #0,v_LOFCprList(a0)
  354.  
  355. * scroll down 8 bitmap 1
  356.  
  357.     move.l    dsp_RasInfo(a2),a0
  358.     move.w    #32+16,ri_RxOffset(a0)    ; offset into bitmap
  359.     move.w    #32+16-8,ri_RyOffset(a0)
  360.  
  361.     bsr    Make_Copper_List
  362.  
  363.     move.l    dsp_View(a2),a0
  364.     move.l    v_LOFCprList(a0),list1_down8
  365.     move.l    #0,v_LOFCprList(a0)
  366.  
  367. * scroll 0 bitmap 2
  368.  
  369.     move.l    dsp_RasInfo(a2),a0
  370.     move.w    #32+16,ri_RxOffset(a0)    ; offset into bitmap
  371.     move.w    #32+16,ri_RyOffset(a0)
  372.  
  373.     move.l    display,a2
  374.     move.l    dsp_RasInfo(a2),a1
  375.     move.l    bitmap2,ri_BitMap(a1)
  376.     lea    status_rastinfo,a1
  377.     move.l    st_bitmap2,ri_BitMap(a1)
  378.  
  379.     bsr    Make_Copper_List
  380.  
  381.     move.l    dsp_View(a2),a0
  382.     move.l    v_LOFCprList(a0),list2
  383.     move.l    #0,v_LOFCprList(a0)
  384.  
  385. * scroll right 4 bitmap 2
  386.  
  387.     move.l    dsp_RasInfo(a2),a0
  388.     move.w    #32+16-4,ri_RxOffset(a0)    ; offset into bitmap
  389.     move.w    #32+16,ri_RyOffset(a0)
  390.  
  391.     bsr    Make_Copper_List
  392.  
  393.     move.l    dsp_View(a2),a0
  394.     move.l    v_LOFCprList(a0),list2_right4
  395.     move.l    #0,v_LOFCprList(a0)
  396.  
  397. * scroll left 4 bitmap 2
  398.  
  399.     move.l    dsp_RasInfo(a2),a0
  400.     move.w    #32+16+4,ri_RxOffset(a0)    ; offset into bitmap
  401.     move.w    #32+16,ri_RyOffset(a0)
  402.  
  403.     bsr    Make_Copper_List
  404.  
  405.     move.l    dsp_View(a2),a0
  406.     move.l    v_LOFCprList(a0),list2_left4
  407.     move.l    #0,v_LOFCprList(a0)
  408.  
  409. * scroll up 4 bitmap 2
  410.  
  411.     move.l    dsp_RasInfo(a2),a0
  412.     move.w    #32+16,ri_RxOffset(a0)    ; offset into bitmap
  413.     move.w    #32+16+4,ri_RyOffset(a0)
  414.  
  415.     bsr    Make_Copper_List
  416.  
  417.     move.l    dsp_View(a2),a0
  418.     move.l    v_LOFCprList(a0),list2_up4
  419.     move.l    #0,v_LOFCprList(a0)
  420.  
  421. * scroll down 4 bitmap 2
  422.  
  423.     move.l    dsp_RasInfo(a2),a0
  424.     move.w    #32+16,ri_RxOffset(a0)    ; offset into bitmap
  425.     move.w    #32+16-4,ri_RyOffset(a0)
  426.  
  427.     bsr    Make_Copper_List
  428.  
  429.     move.l    dsp_View(a2),a0
  430.     move.l    v_LOFCprList(a0),list2_down4
  431.     move.l    #0,v_LOFCprList(a0)
  432.  
  433. * scroll right 12 bitmap 2
  434.  
  435.     move.l    dsp_RasInfo(a2),a0
  436.     move.w    #32+4,ri_RxOffset(a0)    ; offset into bitmap
  437.     move.w    #32+16,ri_RyOffset(a0)
  438.  
  439.     bsr    Make_Copper_List
  440.  
  441.     move.l    dsp_View(a2),a0
  442.     move.l    v_LOFCprList(a0),list2_right12
  443.     move.l    #0,v_LOFCprList(a0)
  444.  
  445. * scroll left 12 bitmap 2
  446.  
  447.     move.l    dsp_RasInfo(a2),a0
  448.     move.w    #32+16+12,ri_RxOffset(a0)    ; offset into bitmap
  449.     move.w    #32+16,ri_RyOffset(a0)
  450.  
  451.     bsr    Make_Copper_List
  452.  
  453.     move.l    dsp_View(a2),a0
  454.     move.l    v_LOFCprList(a0),list2_left12
  455.     move.l    #0,v_LOFCprList(a0)
  456.  
  457. * scroll left 12 bitmap 2
  458.  
  459.     move.l    dsp_RasInfo(a2),a0
  460.     move.w    #32+16,ri_RxOffset(a0)    ; offset into bitmap
  461.     move.w    #32+16+12,ri_RyOffset(a0)
  462.  
  463.     bsr    Make_Copper_List
  464.  
  465.     move.l    dsp_View(a2),a0
  466.     move.l    v_LOFCprList(a0),list2_up12
  467.     move.l    #0,v_LOFCprList(a0)
  468.  
  469. * scroll down 12 bitmap 2
  470.  
  471.     move.l    dsp_RasInfo(a2),a0
  472.     move.w    #32+16,ri_RxOffset(a0)    ; offset into bitmap
  473.     move.w    #32+16-12,ri_RyOffset(a0)
  474.  
  475.     bsr    Make_Copper_List
  476.  
  477.     move.l    dsp_View(a2),a0
  478.     move.l    v_LOFCprList(a0),list2_down12
  479.  
  480.     jsr    Start_Editor
  481.     move.w    d0,d1
  482.     bne.s    .ono_error
  483.     jsr    Field_Editor
  484. .ono_error
  485.     jsr    Stop_Editor
  486.  
  487.     move.l    oldview,a1        ; Load our original view.
  488.     GRAFCALL LoadView
  489.  
  490.     move.l    display,a2        ; Free Copper list structures.
  491.     move.l    dsp_ViewPort(a2),a0
  492.     GRAFCALL FreeVPortCopLists
  493.  
  494.     lea    status_view_port,a0
  495.     GRAFCALL FreeVPortCopLists
  496.  
  497.  
  498.     move.l    list2_down12,a0
  499.     GRAFCALL FreeCprList
  500.     move.l    list2_up12,a0
  501.     GRAFCALL FreeCprList
  502.     move.l    list2_left12,a0
  503.     GRAFCALL FreeCprList
  504.     move.l    list2_right12,a0
  505.     GRAFCALL FreeCprList
  506.  
  507.     move.l    list2_down4,a0
  508.     GRAFCALL FreeCprList
  509.     move.l    list2_up4,a0
  510.     GRAFCALL FreeCprList
  511.     move.l    list2_left4,a0
  512.     GRAFCALL FreeCprList
  513.     move.l    list2_right4,a0
  514.     GRAFCALL FreeCprList
  515.  
  516.     move.l    list2,a0
  517.     GRAFCALL FreeCprList
  518.  
  519.     move.l    list1_down8,a0
  520.     GRAFCALL FreeCprList
  521.     move.l    list1_up8,a0
  522.     GRAFCALL FreeCprList
  523.     move.l    list1_left8,a0
  524.     GRAFCALL FreeCprList
  525.     move.l    list1_right8,a0
  526.     GRAFCALL FreeCprList
  527.  
  528.     move.l    list1,a0
  529.     GRAFCALL FreeCprList
  530.  
  531. CleanUp
  532.     move.l    status_color_map,d0
  533.     beq    .ll3
  534.     move.l    d0,a0
  535.     GRAFCALL FreeColorMap
  536.  
  537. .ll3    move.l    grid_field,d0
  538.     beq.s    .ll4
  539.     move.l    d0,a1
  540.     move.l    #GRIDF_SIZE,d0
  541.     EXECCALL FreeMem
  542.  
  543. .ll4    move.l    display,d0    ; Free our display structure.
  544.     beq    .ll601
  545.     move.l    d0,a0
  546.     CALLEXT    FreeDisplay
  547.  
  548. .ll601
  549.     move.l    st_bitmap2,d0
  550.     beq.s    .ll602
  551.     move.l    d0,a0
  552.     CALLEXT EG_FreeBitMap
  553.  
  554. .ll602
  555.     move.l    st_bitmap1,d0
  556.     beq.s    .ll6
  557.     move.l    d0,a0
  558.     CALLEXT EG_FreeBitMap
  559.  
  560. .ll6    move.l    bitmapg,d0
  561.     beq.s    .ll62
  562.     move.l    d0,a0
  563.     CALLEXT EG_FreeBitMap
  564.  
  565. .ll62    move.l    bitmap2,d0
  566.     beq.s    .ll7
  567.     move.l    d0,a0
  568.     CALLEXT EG_FreeBitMap
  569.  
  570. .ll7    move.l    bitmap1,d0
  571.     beq.s    .ll83
  572.     move.l    d0,a0
  573.     CALLEXT EG_FreeBitMap
  574.  
  575. .ll83    move.l    _ReqToolsBase,d0
  576.     beq.s    .ll82
  577.     CLOSELIB _ReqToolsBase
  578.  
  579. .ll82    move.l    _DOSBase,d0
  580.     beq.s    .ll81
  581.     CLOSELIB _DOSBase
  582.  
  583. .ll81    move.l    _GfxBase,d0
  584.     beq.s    .ll80
  585.     CLOSELIB _GfxBase
  586.  
  587. .ll80    move.l    _IntuitionBase,d0
  588.     beq    .ll8
  589.     CLOSELIB _IntuitionBase
  590.  
  591. .ll8
  592.  
  593. .ll9    move.l    old_stack,sp
  594.     rts
  595.  
  596. *****************************************
  597.  
  598. Make_Copper_List
  599.     move.l    dsp_View(a2),a0
  600.     lea    status_view_port,a1
  601.     GRAFCALL MakeVPort
  602.     move.l    dsp_View(a2),a0
  603.     move.l    dsp_ViewPort(a2),a1
  604.     GRAFCALL MakeVPort
  605.     move.l    dsp_View(a2),a1
  606.     GRAFCALL MrgCop
  607.     rts
  608.  
  609.  
  610.  
  611.  
  612.  
  613.  
  614. ******************************************
  615.  
  616. grid_field    dc.l    0
  617.  
  618. _ExtGfxBase    dc.l    0
  619. _IntuitionBase    dc.l    0
  620. _GfxBase    dc.l    0
  621. _DOSBase    dc.l    0
  622. _ReqToolsBase    dc.l    0
  623. old_stack    dc.l    0
  624. st_bitmap1    dc.l    0    Bitmap for status display
  625. st_bitmap2    dc.l    0    Bitmap for status display
  626. bitmap1        dc.l    0    *BitMap Display 1
  627. bitmap2        dc.l    0    *BitMap Display 2
  628. bitmapg        dc.l    0    *BitMap graphics images
  629. display        dc.l    0
  630. oldview        dc.l    0
  631. status_color_map    dc.l    0
  632.  
  633. list1        dc.l    0    *CopperList display 1
  634. list2        dc.l    0    *CopperList display 2
  635.  
  636. list2_right4    dc.l    0
  637. list1_right8    dc.l    0
  638. list2_right12    dc.l    0
  639.  
  640. list2_left4    dc.l    0
  641. list1_left8    dc.l    0
  642. list2_left12    dc.l    0
  643.  
  644. list2_down4    dc.l    0
  645. list1_down8    dc.l    0
  646. list2_down12    dc.l    0
  647.  
  648. list2_up4    dc.l    0
  649. list1_up8    dc.l    0
  650. list2_up12    dc.l    0
  651.  
  652. bd_ColorMap    dc.l    0
  653.  
  654. new_disp    dc.w    D_x
  655.         dc.w    D_y
  656.         dc.w    V_SPRITES
  657.  
  658. status_view_port
  659.         ds.b    vp_SIZEOF
  660.         even
  661. status_rastinfo
  662.         ds.b    ri_SIZEOF
  663.  
  664. colors        dc.w    $000,$555 ; col 0 & 1
  665.         dc.w    $f20,$5c3 ; col 2 & 3
  666.         dc.w    $fe0,$13d ; col 4 & 5
  667.         dc.w    $333,$999 ; col 6 & 7
  668.         dc.w    $000,$000 ; col 8 & 9
  669.         dc.w    $000,$000 ; col 10 & 11
  670.         dc.w    $000,$000 ; col 12 & 13
  671.         dc.w    $000,$000 ; col 14 & 15
  672.         dc.w    $000,$ddd ; col 16 & 17 sp0&1
  673.         dc.w    $cbb,$ba9 ; col 18 & 19
  674.         dc.w    $987,$875 ; col 20 & 21 sp2&3
  675.         dc.w    $764,$743 ; col 22 & 23
  676.         dc.w    $f60,$d20 ; col 24 & 25 sp4&5
  677.         dc.w    $fe0,$b00 ; col 26 & 27
  678.         dc.w    $0d0,$0cc ; col 28 & 29 sp6&7
  679.         dc.w    $06f,$00a ; col 30 & 31
  680.  
  681. IntName        dc.b    'intuition.library',0
  682.         even
  683. ReqToolsName    REQTOOLSNAME
  684.         even
  685. DosName        DOSNAME
  686.         even
  687. GFXName        GRAPHICSNAME
  688.         even
  689.  
  690. graphics_file_name    dc.b    'boulders',0
  691.  
  692.